aboutsummaryrefslogtreecommitdiffstats
diff options
context:
space:
mode:
Diffstat
-rw-r--r--Makefile.am8
-rwxr-xr-xautogen.sh19
-rw-r--r--configure.ac134
-rw-r--r--src/Makefile.am23
-rw-r--r--tests/Makefile.am16
-rw-r--r--tests/internals/Makefile.am15
6 files changed, 0 insertions, 215 deletions
diff --git a/Makefile.am b/Makefile.am
deleted file mode 100644
index 9d47e04..0000000
--- a/Makefile.am
+++ /dev/null
@@ -1,8 +0,0 @@
-SUBDIRS = src tests
-
-vagrant-clean:
- -for i in vagrant/*/Vagrantfile; do cd `dirname $$i` && (vagrant destroy -f || true) ; cd $$OLDPWD; done
- -rm -Rf vagrant/*/.vagrant vagrant/*/*.log
-
-vagrant-test:
- -vagrant/test.rb
diff --git a/autogen.sh b/autogen.sh
deleted file mode 100755
index e3844a7..0000000
--- a/autogen.sh
+++ /dev/null
@@ -1,19 +0,0 @@
-#!/bin/bash -e
-
-autoreconf -fi
-
-if [ "$1" == "-d" ]; then
- shift;
- echo "Running ./configure"
- echo
- ./configure "$@"
-elif [ -n "$1" ]; then
- echo
- echo "./configure $@"
- ./configure "$@"
-else
- echo
- echo "autogen.sh completed successfully."
- echo "Now run ./configure with the appropriate flags and then make."
-fi
-
diff --git a/configure.ac b/configure.ac
deleted file mode 100644
index 390c393..0000000
--- a/configure.ac
+++ /dev/null
@@ -1,134 +0,0 @@
-AC_INIT([bindfs],[1.18.2],[martin.partel@gmail.com])
-
-AM_INIT_AUTOMAKE([foreign serial-tests])
-AC_CONFIG_HEADERS([config.h])
-
-AC_PROG_CC
-AC_LANG(C)
-LT_INIT
-
-# --enable and --with options
-AC_ARG_ENABLE([debug-output],
- [AS_HELP_STRING([--enable-debug-output], [enable debug output])])
-AC_ARG_WITH([core-foundation],
- AS_HELP_STRING([--with-core-foundation], [(MacOS only) link against Core Foundation @<:@default=no@:>@]))
-AC_ARG_ENABLE([macos-fs-link],
- [AS_HELP_STRING([--disable-macos-fs-link], [(MacOS only) don't install link to /Library/Filesystems - disables 'mount -t bindfs' and /etc/fstab support])])
-AC_ARG_WITH([fuse2],
- [AS_HELP_STRING([--with-fuse2], [link against libfuse 2.x (default: autodetect, preferring 3.x)])])
-AC_ARG_WITH([fuse3],
- [AS_HELP_STRING([--with-fuse3], [link against libfuse 3.x (default: autodetect, preferring 3.x)])])
-
-if test x"$enable_debug_output" = "xyes" ; then
- AC_DEFINE([BINDFS_DEBUG], [1], [Define to 1 to enable debugging messages])
-fi
-
-if test x"$with_core_foundation" = "xyes" ; then
- AC_MSG_NOTICE([Linking with Core Foundation])
- LDFLAGS="${LDFLAGS} -framework CoreFoundation"
-fi
-
-AM_CONDITIONAL([INSTALL_MACOS_FS_LINK], [case $build_os in darwin* ) test x"$enable_macos_fs_link" != "xno" ;; * ) false ;; esac])
-
-# _XOPEN_SOURCE is >= 500 for pread/pwrite; >= 700 for utimensat.
-# __BSD_VISIBLE is for flock() on FreeBSD. It otherwise gets hidden by _XOPEN_SOURCE.
-# _BSD_SOURCE is for stat() nanosecond precision and lutimes().
-# _DEFAULT_SOURCE is the new non-deprecated version of _BSD_SOURCE.
-# _DARWIN_BETTER_REALPATH fixes MacOS realpath() broken around Catalina (#83).
-# _DARWIN_C_SOURCE for DT_LNK (#163)
-my_CPPFLAGS="-D_REENTRANT -D_FILE_OFFSET_BITS=64 -D_XOPEN_SOURCE=700 -D__BSD_VISIBLE=1 -D_BSD_SOURCE -D_DEFAULT_SOURCE -D_DARWIN_BETTER_REALPATH -D_DARWIN_C_SOURCE"
-
-dnl libfuse >=3.17 started requiring gnu11 from the C compiler
-AS_IF([test "x$with_fuse2" = "xyes"], [
- my_std=c99
-], [
- my_std=gnu11
-])
-
-my_CFLAGS="-std=${my_std} -Wall -Wextra -Wpedantic -fno-common"
-case $build_os in
- darwin* )
- # For MacFuse 5.x (2025-06-08)
- my_CFLAGS="${my_CFLAGS} -Wno-language-extension-token -Wno-dollar-in-identifier-extension -DFUSE_DARWIN_ENABLE_EXTENSIONS=0"
- ;;
-esac
-my_LDFLAGS="-pthread"
-AC_SUBST([my_CPPFLAGS])
-AC_SUBST([my_CFLAGS])
-AC_SUBST([my_LDFLAGS])
-
-# Checks for platform-specific stuff
-AC_CHECK_HEADERS([sys/file.h])
-AC_CHECK_FUNCS([lutimes utimensat])
-AC_CHECK_FUNCS([setxattr getxattr listxattr removexattr])
-AC_CHECK_FUNCS([lsetxattr lgetxattr llistxattr lremovexattr])
-AC_COMPILE_IFELSE(
- [AC_LANG_PROGRAM([[
- #define BSD_SOURCE_
- #include <sys/types.h>
- #include <sys/stat.h>
- #include <unistd.h>
- void foo() { struct stat st; st.st_mtim.tv_nsec = 123; }
- ]])],
- [AC_DEFINE(
- [HAVE_STAT_NANOSEC],
- [1],
- [Define if struct stat has st_mtim.tv_nsec etc.]
- )]
-)
-
-# Check for fuse
-
-AC_DEFUN([CHECK_FUSE2],
- [PKG_CHECK_MODULES([fuse], [fuse >= 2.9.0],
- [
- AC_DEFINE([HAVE_FUSE_29], [1], [Have FUSE >= 2.9.0])
- AC_DEFINE([FUSE_USE_VERSION], [26], [FUSE API VERSION = 2.6])
- ],
- [PKG_CHECK_MODULES([fuse], [fuse >= 2.8.0],
- [
- AC_DEFINE([FUSE_USE_VERSION], [26], [FUSE API VERSION = 2.6])
- ],
- [$1]
- )]
- )]
-)
-
-AC_DEFUN([CHECK_FUSE3],
- [PKG_CHECK_MODULES([fuse3], [fuse3 >= 3.4.0],
- [
- AC_DEFINE([HAVE_FUSE_3], [1], [Have FUSE >= 3.0])
- AC_DEFINE([FUSE_USE_VERSION], [34], [FUSE API VERSION = 3.4])
- ],
- [$1]
- )]
-)
-
-AC_DEFUN([CHECK_FUSE_T],
- [PKG_CHECK_MODULES([fuse_t], [fuse-t >= 1.0.0],
- [
- AC_DEFINE([HAVE_FUSE_T], [1], [Have FUSE >= 1.0.0])
- AC_DEFINE([FUSE_USE_VERSION], [34], [FUSE API VERSION = 3.4])
- ],
- [$1]
- )]
-)
-
-
-AS_IF([test "x$with_fuse2" = "xyes"],
- [CHECK_FUSE2([AC_MSG_ERROR([FUSE 2 not found])])],
- [AS_IF([test "x$with_fuse3" = "xyes"],
- [CHECK_FUSE3([AC_MSG_ERROR([FUSE 3 not found])])],
- [AS_IF([test "x$with_fuse_t" = "xyes"],
- [CHECK_FUSE_T([AC_MSG_ERROR([FUSE-T not found])])],
- [CHECK_FUSE3([CHECK_FUSE2([CHECK_FUSE_T([AC_MSG_ERROR([FUSE not found])])])])]
- )]
- )]
-)
-
-AC_CONFIG_FILES([Makefile \
- src/Makefile \
- tests/Makefile \
- tests/internals/Makefile])
-AC_OUTPUT
-
diff --git a/src/Makefile.am b/src/Makefile.am
deleted file mode 100644
index 4c24816..0000000
--- a/src/Makefile.am
+++ /dev/null
@@ -1,23 +0,0 @@
-## Process this file with automake to produce Makefile.in
-
-bin_PROGRAMS = bindfs
-
-noinst_HEADERS = debug.h permchain.h userinfo.h arena.h misc.h usermap.h rate_limiter.h
-bindfs_SOURCES = bindfs.c debug.c permchain.c userinfo.c arena.c misc.c usermap.c rate_limiter.c
-
-AM_CPPFLAGS = ${my_CPPFLAGS} ${fuse_CFLAGS} ${fuse3_CFLAGS} ${fuse_t_CFLAGS}
-AM_CFLAGS = ${my_CFLAGS}
-bindfs_LDADD = ${fuse_LIBS} ${fuse3_LIBS} ${fuse_t_LIBS} ${my_LDFLAGS}
-
-man_MANS = bindfs.1
-
-if INSTALL_MACOS_FS_LINK
-bindfs_BUNDLEDIR = $(DESTDIR)/Library/Filesystems/bindfs.fs
-bindfs_BUNDLEBINDIR = "${bindfs_BUNDLEDIR}/Contents/Resources"
-
-install-exec-hook:
- (mkdir -p "${bindfs_BUNDLEBINDIR}"; ln -sf "${bindir}/bindfs" "${bindfs_BUNDLEBINDIR}/mount_bindfs")
-
-uninstall-hook:
- (rm -rf ${bindfs_BUNDLEDIR})
-endif
diff --git a/tests/Makefile.am b/tests/Makefile.am
deleted file mode 100644
index 742899b..0000000
--- a/tests/Makefile.am
+++ /dev/null
@@ -1,16 +0,0 @@
-
-UNAME_S := $(shell uname -s)
-
-AM_CPPFLAGS = ${my_CPPFLAGS}
-AM_CFLAGS = ${my_CFLAGS}
-
-noinst_PROGRAMS = readdir_inode utimens_nofollow fcntl_locker odirect_read odirect_write test_dir_rewind
-readdir_inode_SOURCES = readdir_inode.c
-utimens_nofollow_SOURCES = utimens_nofollow.c
-fcntl_locker_SOURCES = fcntl_locker.c
-odirect_read_SOURCES = odirect_read.c
-odirect_write_SOURCES = odirect_write.c
-test_dir_rewind_SOURCES = test_dir_rewind.c
-
-TESTS = test_bindfs.rb
-SUBDIRS = internals
diff --git a/tests/internals/Makefile.am b/tests/internals/Makefile.am
deleted file mode 100644
index f0b86e6..0000000
--- a/tests/internals/Makefile.am
+++ /dev/null
@@ -1,15 +0,0 @@
-
-noinst_HEADERS = test_common.h
-noinst_PROGRAMS = test_internals test_rate_limiter
-test_internals_SOURCES = test_internals.c test_common.c $(top_srcdir)/src/misc.c $(top_srcdir)/src/arena.c
-test_rate_limiter_SOURCES = test_rate_limiter.c test_common.c $(top_srcdir)/src/rate_limiter.c
-
-test_internals_CPPFLAGS = ${my_CPPFLAGS} ${fuse_CFLAGS} ${fuse3_CFLAGS} -I. -I$(top_srcdir)/src
-test_internals_CFLAGS = ${my_CFLAGS}
-test_internals_LDADD = ${my_LDFLAGS}
-
-test_rate_limiter_CPPFLAGS = ${my_CPPFLAGS} ${fuse_CFLAGS} ${fuse3_CFLAGS} -I. -I$(top_srcdir)/src
-test_rate_limiter_CFLAGS = ${my_CFLAGS}
-test_rate_limiter_LDADD = ${my_LDFLAGS}
-
-TESTS = test_internals_valgrind.sh test_rate_limiter_valgrind.sh
generated by cgit v1.2.3 (git 2.39.1) at 2025-10-16 00:24:25 +0000